Here's an example where I have a dataset of 49 pigs (indexed by $i$) whose weights are observed over 9 weeks (indexed by $t$). I simulated an experiment by having some pigs put on more weight (see code below). While all pigs put on kgs over time, the yellow line looks a bit steeper: enter image description here

Do the two lines really have different slopes? The RE model is

$$E[\mathtt{weight_{it}} \vert t, \mathtt{treated_i} ] = \mu + \alpha_i + \delta_t + \beta \cdot \mathtt{treated_i} + \gamma_t \cdot \mathbf{I}(\mathtt{week=t}) \cdot \mathtt{treated_i} $$

Here the effect of treatment is a function of time: $$\beta + \gamma_t$$

You can test the hypothesis that effect does not vary with time by testing the joint null that $\gamma_2,\dots,\gamma_9=0$ against the alternative that they are not zero. Since we need to drop one time dummy, the effect in week 1 is not identified. This means that $\beta = (\beta_T + \gamma_1)$ and everything will be relative to the impact in week 1.

Here's the Stata output:

. capture ssc install coefplot

. webuse pig, clear
(Longitudinal analysis of pig weights)

. xtset id week 

Panel variable: id (strongly balanced)
 Time variable: week, 1 to 9
         Delta: 1 unit

. generate treated = mod(id,2)

. replace weight = weight*(1 + .029*week/9) if treated == 1
(216 real changes made)

. xtreg weight i.week##i.treated, re vce(cluster id)

Random-effects GLS regression                   Number of obs     =        432
Group variable: id                              Number of groups  =         48

R-squared:                                      Obs per group:
     Within  = 0.9860                                         min =          9
     Between = 0.0358                                         avg =        9.0
     Overall = 0.9327                                         max =          9

                                                Wald chi2(17)     =    6567.80
corr(u_i, X) = 0 (assumed)                      Prob > chi2       =     0.0000

                                    (Std. err. adjusted for 48 clusters in id)
------------------------------------------------------------------------------
             |               Robust
      weight | Coefficient  std. err.      z    P>|z|     [95% conf. interval]
-------------+----------------------------------------------------------------
        week |
          2  |   6.833333   .2480495    27.55   0.000     6.347165    7.319501
          3  |   13.85417   .4551682    30.44   0.000     12.96205    14.74628
          4  |   19.47917   .4884237    39.88   0.000     18.52187    20.43646
          5  |   25.45833   .6543407    38.91   0.000     24.17585    26.74082
          6  |   31.60417   .6799763    46.48   0.000     30.27144     32.9369
          7  |   37.41667   .8166819    45.82   0.000       35.816    39.01733
          8  |   44.20833   .9016777    49.03   0.000     42.44108    45.97559
          9  |   49.85417   1.079434    46.19   0.000     47.73852    51.96982
             |
   1.treated |   .7066298   .7226836     0.98   0.328    -.7098042    2.123064
             |
week#treated |
        2 1  |  -.0211066   .3319502    -0.06   0.949    -.6717171     .629504
        3 1  |   .2761475   .6378184     0.43   0.665    -.9739536    1.526249
        4 1  |   .2849352   .6875297     0.41   0.679    -1.062598    1.632469
        5 1  |   .0804423   .9307069     0.09   0.931     -1.74371    1.904594
        6 1  |   .6581483   .9600435     0.69   0.493    -1.223502    2.539799
        7 1  |   1.376338   1.145815     1.20   0.230    -.8694176    3.622095
        8 1  |   1.860593   1.295432     1.44   0.151    -.6784076    4.399593
        9 1  |   2.806245   1.604311     1.75   0.080    -.3381472    5.950638
             |
       _cons |   24.70833   .4370002    56.54   0.000     23.85183    25.56484
-------------+----------------------------------------------------------------
     sigma_u |  3.9696885
     sigma_e |   2.118182
         rho |  .77838142   (fraction of variance due to u_i)
------------------------------------------------------------------------------

. estimates store re_model

. testparm week#treated

 ( 1)  2.week#1.treated = 0
 ( 2)  3.week#1.treated = 0
 ( 3)  4.week#1.treated = 0
 ( 4)  5.week#1.treated = 0
 ( 5)  6.week#1.treated = 0
 ( 6)  7.week#1.treated = 0
 ( 7)  8.week#1.treated = 0
 ( 8)  9.week#1.treated = 0

           chi2(  8) =    8.06
         Prob > chi2 =    0.4272

. coefplot re_model, keep(*.week#1.treated) xline(0) label ///
> title("p-value = `=r(p)'*") ///
> note("*The p-value for the null that all time x treated  effects are zero again alternative that they are all not equal to zero.")

Here's the graph of the week x treatment interactions ($\gamma_2,\ldots,\gamma_9$): enter image description here

Though there is a suggestive trend of bigger effects over time, the individual confidence intervals cover zero. Hence, none of the estimated time x treatment effects is statistically distinguishable from zero. The joint p-value that they all zero is 0.43, so we would not reject the joint null either.

The coefficients on week dummies capture the fact that pigs gain weight over time (the $\delta_t$s).

You have multiple covariates, but the idea is the same as with one. You may want to correct your inference for multiple hypothesis testing since you will be testing many parameters.